Arduino Solar Tracker, Get More From Your Solar Panels

If you’ve installed solar panels on a camper van to provide you with electricity on your camping trip or at home to supplement your electricity usage or take your home completely off grid then you probably know that the panels work the best when they are aligned directly towards the sun. This sounds simple enough, except that the sun moves throughout the day. This is why there are now a number of different mechanisms which work on a range of principles with the purpose of aligning your panel or array of panels directly towards the sun, called a solar tracker.

There are two principle types of trackers, single and duel axis trackers. Single axis trackers are adjusted every month or so account for seasonal changes in the suns position, the single axis is then used to track the daily movement of the sun across the sky. Duel axis trackers eliminate the need for monthly adjustment by using one axis to track the suns daily movement and another axis to track the seasonal movement. A single axis solar tracker improves solar output by around 25% and a dual axis tracker by around 40% according to this article on Altestore.

This solar tracker control system is designed to take light measurements from the east and west (left and right) side of the solar panel and determine which way to move the panel to point it directly at the source of the light. A servo is used to actuate the panel tracker; these are available in a broad range of sizes and can be scaled according to your panel size. Although this tracker is single axis, the two sensors and servo can simply be duplicated to provide dual axis control.

This project assumes you know the basics of Arduino programming, otherwise read our article on getting started with Arduino.

You could also take this project further by building your own solar panel as well, here is our guide on how to build a solar panel at home. If you are thinking of switching some or all of your homes power requirements to solar power, read our article on switching to solar power first.

Update: After numerous requests to include information on the modifications required to the circuit as well as to the code needed to drive a linear actuator for heavier panels or arrays of panels, the article is now available – Arduino Solar Tracker – Linear Actuator

What You Will Need For A Solar Tracker

• An Arduino (Uno used here) – Buy Here
• Single Axis Tracking Stand (Brief DIY Design Shown Below)
• 2 x 4.7K Resistors – Buy Here
• 2 x LDRs – Buy Here
• PWM Servo – Buy Here

How To Make The Control System

First you need to start by assembling the components onto your solar panel, or breadboard. The LDRs (light dependent resistors) or PRs (photo-resistors) change resistance with changing light, therefore they need to be connected in such a way that the changing resistance is converted into a changing voltage signal which the Arduino understands. The servo is controlled through one of the Arduino’s PWM outputs.

Assemble the Components

If you are going to be installing the solar tracker permanently then you may want to solder the resistors and LDRs together so that they cannot come loose. If you are simply trying this project for fun then a breadboard is perfect.

The basic circuit for the connection of the LDRs and servo to the Arduino is shown below:

A breadboard connection diagram is shown below:

The resistors R1 and R2 are each 4.7K, the PR1 and PR2 are the two LDRs and the servo can be any PWM hobby servo. If you are using a servo larger than 9 grams then the Arduino will probably not be able to supply it enough power to achieve its full torque capability, you will need to supply the servo directly with its own 5V power source.

If you are making this a permanent installation, then it is best to solder the resistors right up near the LDRs on the panel. This way you can run a single 4 core wire from the control box up to the sensors on the panel, the four cores will be 5V, Gnd and then signal 1 and 2 from the LDRs. Once your LDRs and resistors have been soldered together, you can mount them on your solar panel. Mount the LDRs on the east and west (left and right) sides of the panel facing towards the sun. Make sure that they are not shaded in any way by the frame and have an unobstructed view of the sun.

A breadboard has been used in this project purely to distribute the Ardunio’s 5V power supply to both the resistors and the servo.

The servo needs to be sized according to the size of your solar panel. The panel used in this example is small and relatively light; a small servo was therefore used and is powered by the Arduino. For a larger servo (anything above 9 grams), you will need to power the servo externally as the Arduino doesn’t have sufficient capacity for it. Make sure that you connect the external power sources ground to the Arduinos GND as well otherwise the PWM control signal to the servo will not work.

Upload the Sketch

Now you can upload your sketch onto your Arduino, if you haven’t uploaded a sketch before then follow this guide on getting started.

//The DIY Life
//10 October 2016
//Michael Klements

#include <Servo.h> 
 
Servo tracker;  // create servo object to control a servo 
int eastLDRPin = 0;  //Assign analogue pins
int westLDRPin = 1;
int eastLDR = 0;   //Create variables for the east and west sensor values
int westLDR = 0;
int error = 0;
int calibration = 204;  //Calibration offset to set error to zero when both sensors receive an equal amount of light
int trackerPos = 90;    //Create a variable to store the servo position
 
void setup() 
{ 
  tracker.attach(11);  // attaches the servo on pin 11 to the servo object
} 
 
 
void loop() 
{ 
  eastLDR = calibration + analogRead(eastLDRPin);    //Read the value of each of the east and west sensors
  westLDR = analogRead(westLDRPin);
  if(eastLDR<350 && westLDR<350)  //Check if both sensors detect very little light, night time
  {
    while(trackerPos<=160)  //Move the tracker all the way back to face east for sunrise
    {
      trackerPos++;
      tracker.write(trackerPos);
      delay(100);
    }
  }
  error = eastLDR - westLDR;          //Determine the difference between the two sensors.
  if(error>15)        //If the error is positive and greater than 15 then move the tracker in the east direction
  {
    if(trackerPos<=160)  //Check that the tracker is not at the end of its limit in the east direction
    {
      trackerPos++;
      tracker.write(trackerPos);  //Move the tracker to the east
    }
  }
  else if(error<-15)  //If the error is negative and less than -15 then move the tracker in the west direction
  {
    if(trackerPos>20)  //Check that the tracker is not at the end of its limit in the west direction
    {
      trackerPos--;
      tracker.write(trackerPos);  //Move the tracker to the west
    }
  }
  delay(100);
}

Here is the link to download the Solar Tracker code.

Calibrate the Sensor Error

Because of differences between the LDRs, resistors and the resistance of the wire used, there will be a difference between the signal received from both sensors even when they are receiving the same amount of light. This is taken into account by introducing a calibration offset into the calculation, this number will need to be adjusted in your code according to your setup. Adjust this calibration factor where it is declared in the code,

Line 13: int calibration = 204.

The most accurate way to determine this factor is to shine a light equally between both sensors and then use the Serial monitor on your computer to read the values output by the east and west sensor. The difference between these two values will be the calibration offset. The LDRs are very sensitive so the tracker only moves when the difference between them is greater than 15 in the code otherwise it would be continuously tracking forwards and backwards and wasting power.

If you are not familiar with the Serial interface then you can play around with this value until the tracker remains still when a light is shined equally onto both sensors.

Making A Single Axis Tracking Stand

While this article is not intended to detail making a tracking stand because of the extremely diverse range and size of panels available, here is a brief outline on the design along with some key pointers.

Your stand should look something like this when it is complete:

Ideally the stand should be made from aluminium angle as it is strong, durable and suitable for outdoor use but it can also be made from wood, plywood or PVC piping.

The stand is essentially made in two parts, the base and the panel support. They are joined around a pivot point on which the panel support rotates. The servo is mounted onto the base and the arm actuates the panel support.

The panel should protrude from the panel support as little as possible to keep the out of balance load on the servos to a minimum. Ideally, the pivot point should be placed at the centre of gravity of the panel and panel support together so that the servo has an equal load placed on it no matter which direction the panel is facing although this is not always practically possible.

Two servos may be used for heavier panels, one on each side of the panel. The geometry needs to be the same and the servos need to be the same type/model. You can then duplicate the servo code in the software so that both servos are given the same reference position and move together to actuate the panel.

For very heavy panels or for solar arrays, the servos will need to be replaced with stronger stepper motors. The stepper motors will need to be driven by a driver board such as this one.

The stand used in this guide to test the concept and the code has been made up using a camera pan and tilt bracket which was then glued onto a wooden base. Here are some close up photos of the stand.

The Solar Tracker In Operation

Here is a video of the solar tracker in operation indoors with a torch being used to simulate the movement of the sun:

Would you like to learn more about this project? Are you interested in projects similar to this one? Then Practical Arduino Projects is the book for you, available now on Amazon as an eBook or in Print form.

Have you tried out making your own solar tracker? Let us know your experiences, tips and tricks in the comment section below. We would love to see your project as well.